Learn on the fly : A simple Si5351 vfo and bfo with S meter for hombrew transceiver- firmware based on arduino/atmega328p

Si5351 vfo cum bfo with S meter for hombrew trx

Here is a Simple vfo+bfo using Si5351 and a 16X2 lcd with an S-meter. It is based on atmega328 as a controller. The connections for LCD, Si5351 and AVR are explained in may previous post at "A Simple Si5351 based vfo (signal generator) for ham radio use [quick start-setting up and general details]"

The idea is to keep it very basic with some of the essential elements and to use a Rotary encoder for all adjustments.

Basic frequency adjustments using an encoder with varying steps
Option for Receiver Incremental Tuning (RIT)
Option to set a BFO offset and built in bfo signal generation using extra clocks in Si5351
A simple S meter using character LCD
Setting up for Direct Conversion/Superhet/ x4 time clock for SDR (softrock style)
Frequency correction settings for calibrating Si5351+crystal
EEPROM save of last frequency

A simple video of the prototype is shown below. In normal operation it defaults as a vfo. A setup mode (triggered by pressing down the encoder button while switching it on) is used to adjust the parameters

Wiring details can be seen by reading this post

Firmware can be downloaded at this Link

Uploading Firmware to arduino/atmega328 (See: http://www.hobbytronics.co.uk/arduino-xloader)

A reader was asking about the barplot and given below is a snippet to show how to make a simple bar-plot. For S meter, you may use linear or preferably a logarithmic scale (if no op-amps are used to do this at the signal level)

You can customize the characters using this tool Online LCD Character Generator

The code given below is a partial snippet

// include the library code:
#include <LiquidCrystal.h>

int analogInput = A1;

byte graph_simple[8] = {
    B11111,
    B11111,
    B11111,
    B11111,
    B11111,
    B11111,
    B11111,
    B11111,
};

#include <LiquidCrystal.h>
LiquidCrystal lcd(7, 8, 9, 10, 11, 12); //SET CORRECT PINS IN YOUR CASE

void setup()
{
    pinMode(analogInput, INPUT);
    lcd.begin(16, 2);
    lcd.createChar(0, graph_simple);
}

void loop()
{
    value = analogRead(analogInput);
    barplot(value);
}

void barplot(int value)
{
    //ADC value can range from 0-1023
    value = (value * 16.0) / 1023.0; //Scale it to 16
    lcd.clear(); // clear the old bars
    lcd.setCursor(0, 0); //draw graph starting from 0,0
    for (i = 0; i < value; i++) {
        lcd.write(byte(0));
    }
}

Complete source with an i2c lcd

/*
more details of the project at www.riyas.org
This entire program is taken from Jason Mildrum, NT7S and Przemek Sadowski, SQ9NJE.
There is not enough original code written by me to make it worth mentioning.
http://nt7s.com/
http://sq9nje.pl/
http://ak2b.blogspot.com/
*/

#include <Rotary.h>
#include <si5351.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <avr/eeprom.h>

// S meter glyphs
unsigned long previousMillis = 0;
unsigned long starttime = 0;
        
struct settings_t
{
    int32_t bfo_offset ;
    uint32_t vfo ;
    bool quadruple;
    bool superhet;
    bool direct;
    int fcorrection;
}
settings;


byte bar5[8]={B00000,
B11011,
B11011,
B11011,
B11011,
B11011,
B11011,
B00000};

byte bar1[8]={B10000,
B11000,
B11100,
B11110,
B11110,
B11100,
B11000,
B10000};



#define F_MIN        100000000UL               // Lower frequency limit
#define F_MAX        5000000000UL

#define ENCODER_A    3                      // Encoder pin A
#define ENCODER_B    2                      // Encoder pin B
#define ENCODER_BTN  A0
#define TX_BTN  A2
#define SMETER_IN  A1

// LCD - pin assignement in
// LCD defs
#define I2C_ADDR    0x3f  // Define I2C Address where the PCF8574A is
#define BACKLIGHT_PIN     3
#define En_pin  2
#define Rw_pin  1
#define Rs_pin  0
#define D4_pin  4
#define D5_pin  5
#define D6_pin  6
#define D7_pin  7

LiquidCrystal_I2C lcd(I2C_ADDR,En_pin,Rw_pin,Rs_pin,D4_pin,D5_pin,D6_pin,D7_pin);
     
Si5351 si5351;
Rotary r = Rotary(ENCODER_A, ENCODER_B);
volatile uint32_t LSB = 899950000ULL;
volatile uint32_t USB = 900150000ULL;
volatile uint32_t bfo = 900150000ULL; //start in usb
//These USB/LSB frequencies are added to or subtracted from the vfo frequency in the "Loop()"
//In this example my start frequency will be 14.20000 plus 9.001500 or clk0 = 23.2015Mhz
volatile uint32_t vfo = 1420000000ULL / SI5351_FREQ_MULT; //start freq - change to suit
volatile uint32_t radix = 100;  //start step size - change to suit
volatile uint32_t ritstep=1;

volatile int32_t menu=0;  //start step size - change to suit
uint16_t menuoption=0;


boolean changed_f = 0;
String tbfo = "";
boolean rit=0;
boolean txon=0;
boolean savetag=0;
boolean setupmenu=0;
volatile int32_t rit_offset=0;

//------------------------------- Set Optional Features here --------------------------------------
//Remove comment (//) from the option you want to use. Pick only one
//#define IF_Offset //Output is the display plus or minus the bfo frequency
#define Direct_conversion //What you see on display is what you get
//#define FreqX4  //output is four times the display frequency
//--------------------------------------------------------------------------------------------------


/*
MULTI-CLICK: One Button, Multiple Events

Oct 12, 2009
Run checkButton() to retrieve a button event:
Click
Double-Click
Hold
Long Hold
*/

// Button timing variables
int debounce = 20; // ms debounce period to prevent flickering when pressing or releasing the button
int DCgap = 250; // max ms between clicks for a double click event
int holdTime = 2000; // ms hold period: how long to wait for press+hold event
int longHoldTime = 5000; // ms long hold period: how long to wait for press+hold event

// Other button variables
boolean buttonVal = HIGH; // value read from button
boolean buttonLast = HIGH; // buffered value of the button's previous state
boolean DCwaiting = false; // whether we're waiting for a double click (down)
boolean DConUp = false; // whether to register a double click on next release, or whether to wait and click
boolean singleOK = true; // whether it's OK to do a single click
long downTime = -1; // time the button was pressed down
long upTime = -1; // time the button was released
boolean ignoreUp = false; // whether to ignore the button release because the click+hold was triggered
boolean waitForUp = false; // when held, whether to wait for the up event
boolean holdEventPast = false; // whether or not the hold event happened already
boolean longHoldEventPast = false;// whether or not the long hold event happened already

int checkButton()
{ 
int event = 0;
// Read the state of the button
buttonVal = digitalRead(ENCODER_BTN);
// Button pressed down
if (buttonVal == LOW && buttonLast == HIGH && (millis() - upTime) > debounce) {
downTime = millis();
ignoreUp = false;
waitForUp = false;
singleOK = true;
holdEventPast = false;
longHoldEventPast = false;
if ((millis()-upTime) < DCgap && DConUp == false && DCwaiting == true) DConUp = true;
else DConUp = false;
DCwaiting = false;
}
// Button released
else if (buttonVal == HIGH && buttonLast == LOW && (millis() - downTime) > debounce) { 
if (not ignoreUp) {
upTime = millis();
if (DConUp == false) DCwaiting = true;
else {
event = 2;
DConUp = false;
DCwaiting = false;
singleOK = false;
}
}
}
// Test for normal click event: DCgap expired
if ( buttonVal == HIGH && (millis()-upTime) >= DCgap && DCwaiting == true && DConUp == false && singleOK == true) {
event = 1;
DCwaiting = false;
}
// Test for hold
if (buttonVal == LOW && (millis() - downTime) >= holdTime) {
// Trigger "normal" hold
if (not holdEventPast) {
event = 3;
waitForUp = true;
ignoreUp = true;
DConUp = false;
DCwaiting = false;
//downTime = millis();
holdEventPast = true;
}
// Trigger "long" hold
if ((millis() - downTime) >= longHoldTime) {
if (not longHoldEventPast) {
event = 4;
longHoldEventPast = true;
}
}
}
buttonLast = buttonVal;
return event;
}
/**************************************/
/* Interrupt service routine for      */
/* encoder frequency change           */
/**************************************/
ISR(PCINT2_vect) {
  unsigned char result = r.process();
  if (result == DIR_CW)
  {
    if(!setupmenu)
    set_frequency(1);
    else
    setup_menu(1);
  }
  else if (result == DIR_CCW)
  {
    if(!setupmenu)
    set_frequency(-1);
    else
    setup_menu(-1);    
  }
}
/**************************************/
/* Change the frequency               */
/* dir = 1    Increment               */
/* dir = -1   Decrement               */
/**************************************/
void set_frequency(short dir)
{
  savetag=false;
    if(!txon) //lock on tx
 {   
    
    if (dir == 1)
    {
      if(rit)
      rit_offset+= ritstep ;
      else
      vfo += radix; 
    }  
    if (dir == -1)
    {
      if(rit)
      rit_offset-= ritstep;
      else
      vfo -= radix;
    }

  //    if(vfo > F_MAX)
  //      vfo = F_MAX;
  //    if(vfo < F_MIN)
  //      vfo = F_MIN;

   if(rit)
   rit_offset=constrain(rit_offset,-10000,10000);

  
  changed_f = 1;
 }
}
/**************************************/
/* Read the button with debouncing    */
/**************************************/

boolean get_button()
{
  if (!digitalRead(ENCODER_BTN))
  {
    delay(20);
    if (!digitalRead(ENCODER_BTN))
    {
      while (!digitalRead(ENCODER_BTN));
      return 1;
    }
  }
  return 0;
}

/*****************************/
/* display S meter           */
/****************************/
void display_smeter(int strength)

{
// range is 0 to 1024 of adc  
//meter run from position 3 to 14 (12 )
int scale = (strength*15)/1024;
lcd.setCursor(0, 1);
lcd.print("S");
int smeter=(scale*11)/15;
if(smeter<10)
lcd.print(smeter);
else
lcd.print("9");
lcd.print(">");
unsigned long currentMillis = millis();
if (currentMillis - previousMillis >= 1000) {
    previousMillis = currentMillis;
//clear all after a small interval
lcd.setCursor(3, 1);
lcd.print("            ");
lcd.noCursor();
}


// write it and show for 500 milli sec
for (int i = 3; i<scale; i++)
  {
      lcd.setCursor(i, 1);
      lcd.write(byte(0));
      if(smeter>9)
      lcd.print("+");
  }

  
}


void display_rit()
{
  lcd.setCursor(0, 0);
  lcd.print("RIT:            ");
  lcd.setCursor(6, 0);
  lcd.print(rit_offset);
  lcd.print("Hz");  

        lcd.setCursor(15, 0);
        switch (ritstep)
          {
              case 1: 
                  lcd.print("1");
                   break;
              case 100:
                  lcd.print("2");
                   break;
              case 2500:
                  lcd.print("3"); 
                  break;
          }
  
}


/**************************************/
/* Displays the frequency             */
/**************************************/
void display_frequency()
{
  uint16_t f, g;

  lcd.setCursor(0, 0);
  lcd.print("VFO:             ");
  lcd.setCursor(4, 0);
  f = vfo / 1000000;  //variable is now vfo instead of 'frequency'
  Serial.println(vfo);
  
  if (f < 10)
    lcd.print(' ');
  lcd.print(f);
  lcd.print('.');
  f = (vfo % 1000000) / 1000;
  if (f < 100)
    lcd.print('0');
  if (f < 10)
    lcd.print('0');
  lcd.print(f);
  lcd.print('.');
  f = vfo % 1000;
  if (f < 100)
    lcd.print('0');
  if (f < 10)
    lcd.print('0');
  lcd.print(f);
  //lcd.print("Hz");
  lcd.setCursor(0, 1);
  //lcd.print(tbfo);
  //Serial.println(vfo + bfo);
  //Serial.println(tbfo);

}


void show_stored()
{
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("vfo=");
  lcd.print(vfo);
  lcd.print("#");
  if(settings.quadruple)
  lcd.print("Q");
  else
  lcd.print("q");
  lcd.setCursor(0, 1);
  if(settings.superhet)
  lcd.print("S");
  else
  lcd.print("s");

  if(settings.direct)
  lcd.print("D");
  else
  lcd.print("d");
  lcd.print("F:");
  lcd.print   (settings.fcorrection);
  lcd.print("B:");
  lcd.print (settings.bfo_offset);
}

void setup_menu(short dir)
{
  //called in setup mode
      if (dir == 1)
    {
      menu += radix; 
    }  
    if (dir == -1)
    {
      menu -= radix;
    }
  menu=constrain(menu,-10000000,10000000);
}

void  show_vfo_setup()
{

lcd.clear();
lcd.setCursor(0, 0);
lcd.print("VFO SETUP MODE"); 
delay(2000);  
lcd.clear();
//lcd.setCursor(0, 1);
//show_stored();
while(1)
    {
      //delay(300);
      //settings.quadruple=false;
      //settings.superhet=false;
      //settings.direct=true;
      //settings.fcorrection=0;
      //settings.bfo_offset=0;
      int b = checkButton();
      if ((b == 1) && (menuoption==0)) vfosteps();
      if (b == 2) menu_option();
      if (b == 3) holdEvent();
      if (b == 4) longHoldEvent();
      
      if(menuoption==0)
      show_bfo();
      if(menuoption==1)
      show_fcorrection();
      if(menuoption==2)
      show_bits();
    } 
}

void show_fcorrection()
{
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("FREQ CORRECTION");  
}

void show_bits()
{
  lcd.clear();
  lcd.setCursor(0, 0);  
  lcd.print("SH  x4  DC"); 
  lcd.setCursor(0, 1);
  lcd.print(settings.superhet);  
}

void menu_option()
{  
menuoption+=1;
if(menuoption>2)
menuoption=0;  
}

void show_bfo(){
  settings.bfo_offset=menu;       
  uint32_t f, g;
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print(" OFFSET:        ");
  lcd.setCursor(9, 0);
  lcd.print(settings.bfo_offset);
  lcd.setCursor(0, 1);
  lcd.print(" STEP:");
  lcd.print(round(log10(radix)+1));
  if((int(log10(radix)) % 2)==0)
  {
  lcd.setCursor(0, 0);
  lcd.write(byte(1));
  }  
  else
  {
  lcd.setCursor(0, 1);
  lcd.write(byte(1));
  }
  
      
}


void setup()
{
  Serial.begin(19200);
  lcd.begin(16, 2);
  lcd.setBacklightPin(BACKLIGHT_PIN,POSITIVE);
  lcd.setBacklight(HIGH);
  lcd.home ();  
  lcd.clear();
  Wire.begin();

  lcd.createChar(0, bar5); 
  lcd.createChar(1, bar1);   
  lcd.begin(16, 2); 
  lcd.setCursor(5, 0);
  lcd.print("LB7UG");

  lcd.setCursor(4, 1);
  lcd.print("loading");
  delay(1000);
  lcd.clear();
  //read from eeprom
  eeprom_read_block((void*)&settings, (void*)0, sizeof(settings));
  vfo=constrain(settings.vfo,1000000,30000000);
  //vfo=1000000;//remove it after the test run
     if(vfo==1000000|vfo==30000000)
     {
      //dirty hack to fix the first run with eeprom
      settings.quadruple=false;
      settings.superhet=false;
      settings.direct=true;
      settings.fcorrection=0;
      settings.bfo_offset=0;
     }
  bfo= settings.bfo_offset; 

  si5351.set_correction(settings.fcorrection); //**mine. There is a calibration sketch in File/Examples/si5351Arduino-Jason
  //where you can determine the correction by using the serial monitor.

  //initialize the Si5351
  si5351.init(SI5351_CRYSTAL_LOAD_8PF, 27000000); //If you're using a 27Mhz crystal, put in 27000000 instead of 0
  // 0 is the default crystal frequency of 25Mhz.

  si5351.set_pll(SI5351_PLL_FIXED, SI5351_PLLA);
  // Set CLK0 to output the starting "vfo" frequency as set above by vfo = ?

  if (settings.superhet)
  {
  si5351.set_freq((vfo * SI5351_FREQ_MULT) + bfo, SI5351_PLL_FIXED, SI5351_CLK0);
  volatile uint32_t vfoT = (vfo * SI5351_FREQ_MULT) + bfo;
  // Set CLK2 to output bfo frequency
  si5351.set_freq( bfo, 0, SI5351_CLK2);
  }
  //si5351.drive_strength(SI5351_CLK0,SI5351_DRIVE_2MA); //you can set this to 2MA, 4MA, 6MA or 8MA
  //si5351.drive_strength(SI5351_CLK1,SI5351_DRIVE_2MA); //be careful though - measure into 50ohms
  //si5351.drive_strength(SI5351_CLK2,SI5351_DRIVE_2MA); //
if(settings.direct)
  si5351.set_freq((vfo * SI5351_FREQ_MULT), SI5351_PLL_FIXED, SI5351_CLK0);

if(settings.quadruple)
  si5351.set_freq((vfo * SI5351_FREQ_MULT) * 4, SI5351_PLL_FIXED, SI5351_CLK0);

  pinMode(ENCODER_BTN, INPUT_PULLUP);
  pinMode(TX_BTN, INPUT_PULLUP);
  PCICR |= (1 << PCIE2);           // Enable pin change interrupt for the encoder
  PCMSK2 |= (1 << PCINT18) | (1 << PCINT19);
  sei();
  display_frequency();  // Update the display

  
  while(!digitalRead(ENCODER_BTN))
  {
  setupmenu=true;  
  show_vfo_setup();  
  delay(50000);
  }

  
}


void loop()
{

//eeprom timer

unsigned long currentMillis = millis();
if (currentMillis - starttime >= 120000) {
    starttime = currentMillis;
//clear all after a small interval
savetag=true;
}


    
  display_smeter(analogRead(SMETER_IN));
  // Update the display if the frequency has been changed
  
  //tx status
  if(!digitalRead(TX_BTN))  
  txon=true;
  else
  txon=false;
  
  
  if (changed_f)
  {
    if(rit & !txon)
    {
    display_rit();
    }
    else
    {    
    display_frequency();
    //reset rit offset to zero if frequency changed in non rit mode
    rit_offset=0;
    ritstep=1;
    }

    if (settings.superhet)
    {
    if(rit & !txon)  
    si5351.set_freq(((vfo+rit_offset) * SI5351_FREQ_MULT) + bfo, SI5351_PLL_FIXED, SI5351_CLK0);
    else
    si5351.set_freq((vfo * SI5351_FREQ_MULT) + bfo, SI5351_PLL_FIXED, SI5351_CLK0);
    //you can also subtract the bfo to suit your needs
    //si5351.set_freq((vfo * SI5351_FREQ_MULT) - bfo  , SI5351_PLL_FIXED, SI5351_CLK0);
    //set clock2 as bfo
    si5351.set_freq( bfo, 0, SI5351_CLK2);
    }
  
  
  if(settings.direct)
     {
      if(rit & !txon) 
      si5351.set_freq(((vfo+rit_offset) * SI5351_FREQ_MULT), SI5351_PLL_FIXED, SI5351_CLK0);
      else
      si5351.set_freq((vfo * SI5351_FREQ_MULT), SI5351_PLL_FIXED, SI5351_CLK0);

     }
  if(settings.quadruple)
   {
     if(rit & !txon) 
     si5351.set_freq(((vfo+rit_offset) * SI5351_FREQ_MULT) * 4, SI5351_PLL_FIXED, SI5351_CLK0);
     else
     si5351.set_freq((vfo * SI5351_FREQ_MULT) * 4, SI5351_PLL_FIXED, SI5351_CLK0);    
   }
 
     changed_f = 0;
  }

  
if(txon)
{
    display_frequency();
    delay(300);    
}
else
{
    if(rit)
    {
    display_rit();
    delay(100);    
    }    
}    
int b = checkButton();

if (b == 1) clickEvent();
if (b == 2) doubleClickEvent();
if (b == 3) holdEvent();
if (b == 4) longHoldEvent();


if(savetag)
{
//save to eeprom after 30 second of no frequency change
if(vfo !=settings.vfo)
  {
    settings.vfo=vfo;
    eeprom_write_block((const void*)&settings, (void*)0, sizeof(settings));
    savetag=false;
    lcd.clear();
    delay(2000);
    display_frequency();

  }
}


}

void clickEvent() {

if(!rit)
vfosteps();
else
      {
        //steps for RIT
        lcd.setCursor(15, 0);
        switch (ritstep)
          {
              case 1: 
                  ritstep=100;
                  break;
              case 100:
                  ritstep=2500;
                  break;
              case 2500:
                  ritstep=1 ; 
                  break;
          }
          display_rit();
  
     }
}

void doubleClickEvent() {
  rit=!rit;
 if(rit)
 display_rit();
 else
 display_frequency();
 
}

void holdEvent() {
  lcd.setCursor(0, 0);
  lcd.print("HO ");
}

void longHoldEvent() {
  lcd.setCursor(0, 0);
  lcd.print("LO ");
  settings.vfo=vfo;
  eeprom_write_block((const void*)&settings, (void*)0, sizeof(settings));

}


void vfosteps()
{

  
switch (radix)
    {
      case 1:
        radix = 10;
        break;
      case 10:
        radix = 100;
        break;
      case 100:
        radix = 1000;
        break;
      case 1000:
        radix = 10000;
        break;
      case 10000:
        radix = 100000;
        break;
      case 100000:
        radix = 1000000;
        break;
      case 1000000:
        radix = 1;
        break;  
    }//end switch
      //show cursor 
  if(!setupmenu)
  {     
    if(radix<1000)
    lcd.setCursor((13-log10(radix)), 0);
    else if (radix<1000000)
    lcd.setCursor((12-log10(radix)), 0);
    else if (radix=1000000)
    lcd.setCursor(5, 0);
    lcd.cursor(); 
    delay(500);
    lcd.noCursor();
  }
    
}

END

15 comments:

QqFebruary 3, 2018 at 1:17 PM
is there any full of this sourcecode??
UnknownMarch 16, 2018 at 11:17 PM
Please full code
emercitoJuly 31, 2018 at 7:22 AM
Hi. Do you have a si5351 and oled dds fvo with features such as voice lock, color dipsli inversim and more
AnonymousAugust 29, 2018 at 3:12 AM
pore tawwa��
nickolsJanuary 5, 2019 at 4:50 PM
Hallo I am Ciro,IK6AIZ,
I am looking for a ready sketch for Arduino nano clone and 16x2 display NOT I2c, to make the si5351a Arduino nano vfo, with s-meter, bfo frequency, another fixed frequency available from the third output of the si5351a, output meter and possibly also an swr meter. I cannot find anything suitable because all projects I have found do not have everything, I mean the circuit diagram with wiring and the proper relative sketch. Could please someone help me? My email address is: [email protected].
Thanks in advance!!!!
BernardMarch 15, 2019 at 11:06 AM
Hello and thank you for software
Which SI5351 library do you use
Salutations
mircemkOctober 18, 2019 at 2:16 PM
Connection diagram of LCD16x2 on Arduino for .hex code please?
emercitoOctober 24, 2019 at 5:32 AM
Hi
Do you have similar projet for CB radios?
TA3IHDOctober 26, 2019 at 9:14 AM
Can you post me full library?
[email protected]
TihMay 25, 2020 at 10:57 PM
Where I can find si5351.h ...
UnknownSeptember 14, 2020 at 1:35 PM
where can i get the avr/eeprom.h library? thanks
AnonymousApril 28, 2021 at 8:10 AM
Tuan tolong kirim schenatic diagram dan code sketch nya... untuk mencoba...terima kasih banyak sebelumnya... [email protected]
japanacMay 1, 2021 at 5:19 PM
has anyone found a complete program ???
japanacMay 1, 2021 at 5:20 PM
has anyone found a complete program ???

Learn on the fly

Pages

Sunday, December 11, 2016

A simple Si5351 vfo and bfo with S meter for hombrew transceiver- firmware based on arduino/atmega328p

15 comments: